عرض مصدر Arduino/advanced io/shiftout

<noinclude>{{DISPLAYTITLE:الدالة <code>shiftOut()‎</code> في  أردوينو}}</noinclude>
تزيح الدالة <code>shiftOut()‎</code> بايتًا من البيانات إلى رجل محدَّدة مقدار بتٍّ واحدٍ في كل مرة تتغير فيها حالة النبضة على رجل أخرى إلى <code>HIGH</code>. يمكن ترتيب عملية إزاحة البتات وكتابتها على الرجل إمَّا بدءًا من البت الأكثر أهمية (أقصى اليسار) أو من البت الأقل أهمية (أقصى اليمين).
==البنية العامة==
<syntaxhighlight lang="arduino">
shiftOut(dataPin, clockPin, bitOrder, value)
</syntaxhighlight>في كل بت، تقدح الرجل <code>clockPin</code> عملية كتابة البت التالي من القيمة <code>value</code> على الرجل <code>dataPin</code> عند الجبهة الصاعدة للإشارة (أي عندما تنتقل النبضة من <code>LOW</code> إلى <code>HIGH</code>) ثم يجب حينها على الرجل <code>clockPin</code> أن تعود للحالة المنخفضة (<code>LOW</code>) لتشير إلى أنَّ البت كتب على الرجل وأصبح متاحًا.

إن كنت تتعامل مع جهازٍ يعمل أو يولِّد نبضات عند الجبهات الصاعدة، فيجب عليك أن تتأكد أنَّ حالة الرجل <code>clockPin</code> هي <code>LOW</code> قبل استدعاء الدالة <code>shiftOut()‎</code> عبر استدعاء <code>[[Arduino/digital io/digitalwrite|digitalWrite(clockPin, LOW)‎]]</code> مثلًا.

'''ملاحظة''': هذه العملية التي تجريها الدالة هي تنفيذٌ برمجيٌّ؛ توفر أردوينو المكتبة SPI التي تستعمل التنفيذ العتادي لهذه العملية التي تتميز بسرعتها سوى أنَّها تعمل على أرجل معيَّنة فقط.
==المعاملات==
===<code>dataPin</code>===
عددٌ صحيح يشير إلى الرجل التي سيُظهَر عليها كل بت من بتات القيمة <code>value</code> تباعًا.
===<code>clockPin</code>===
عددٌ صحيح يشير إلى الرجل التي تمثِّل نبضات الساعة التي تقدح (عند الجبهة الصاعدة) عملية كتابة بتٍّ واحدٍ على الرجل <code>dataPin</code>.
===<code>bitOrder</code>===
يحدِّد هذا المعامل ترتيب عملية إزاحة البتات المكتوبة على الرجل <code>dataPin</code> عند كل جبهة صاعدة لنبضات الرجل <code>clockPin</code>. يأخذ هذا المعامل القيمة <code>MSBFIRST</code> إن كان أول بت يراد إزاحته وكتابته هو البت الأكثر أهمية أو القيمة <code>LSBFIRST</code> إن كان أول بت يراد إزاحته وكتابته هو البت الأقل أهمية.
===<code>value</code>===
بايتٌ من البيانات يراد إزاحته وإخراجه على الرجل <code>dataPin</code>.
==القيم المعادة==
لا يعاد أي شيء.
==أمثلة==
مثالٌ على استخدام مسجل الإزاحة [https://www.onsemi.com/pub/Collateral/MC74HC595-D.PDF 74HC595] والتحكم به:<syntaxhighlight lang="arduino">
//**************************************************************//
//  Name    : shiftOutCode, Hello World                         //
//  Author  : Carlyn Maw,Tom Igoe                               //
//  Date    : 06 Oct, 2006                                      //
//  Version : 2.0                                               //
//  Notes   : Edited by Hsoub on 06 Nov, 2018.                  //
//          : Code for using a 74HC595 Shift Register           //
//          : to count from 0 to 255                            //
//****************************************************************

// لمسجل الإزاحة ST_CP وصل الرجل 8 مع الرجل
int latchPin = 8;
// لمسجل الإزاحة SH_CP وصل الرجل 12 مع الرجل
int clockPin = 12;
//// لمسجل الإزاحة DS وصل الرجل 11 مع الرجل
int dataPin = 11;

void setup() {
  // تهيئة الأرجل إلى أرجل خرج
  pinMode(latchPin, OUTPUT);
  pinMode(clockPin, OUTPUT);
  pinMode(dataPin, OUTPUT);
}

void loop() {
  // استعمال عداد تصاعدي
  for (int j = 0; j < 256; j++) {
    // منخفضة والإبقاء عليها كذلك طالما تجري عملية النقل latchPin جعل جهد الرجل
    digitalWrite(latchPin, LOW);
    shiftOut(dataPin, clockPin, LSBFIRST, j);
    // لإبلاغ شريحة المسجل latchPin إعادة رفع جهد الرجل  
    // بالتوقف عن انتظار القيمة المراد نقلها وإزاحتها
    digitalWrite(latchPin, HIGH);
    delay(1000);
  }
}
</syntaxhighlight>للاطلاع على كيفية وصل الدارة الإلكترونية المرافقة لهذا المثال، انتقل إلى هذا الدرس.
==ملاحظات وتحذيرات==
يجب تهيئة الرجل <code>dataPin</code> والرجل <code>clockPin</code> مسبقًا إلى وضع الإخراج (output) عبر استدعاء الدالة <code>pinMode()‎</code>.

كتُبَت الدالة <code>shiftOut()‎</code> للعمل على إظهار بايتٍ واحدٍ (8 بت) من البيانات فقط، لذا تتطلب عملية إظهار قيم أكبر من 255 إلى تجزئتها إلى مرحلين كما موضح في الشيفرة التالية:<syntaxhighlight lang="arduino">
// MSBFIRST إزاحة البت الأكثر أهمية أولًا
int data = 500;
// إزاحة البايت العلوي
shiftOut(dataPin, clock, MSBFIRST, (data >> 8));
// إزاحة البايت السفلي
shiftOut(dataPin, clock, MSBFIRST, data);

// LSBFIRST إزاحة البت الأقل أهمية أولًا
data = 500;
// إزاحة البايت السفلي
shiftOut(dataPin, clock, LSBFIRST, data);
// إزاحة البايت العلوي
shiftOut(dataPin, clock, LSBFIRST, (data >> 8));
</syntaxhighlight>
==انظر أيضًا==
* الدالة <code>[[Arduino/advanced io/notone|noTone()‎]]</code>: توقف توليد موجةٍ مربَّعةٍ على رجل معيَّنة أُنشئَت باستعمال الدالة <code>[[Arduino/advanced io/tone|tone()‎]]</code>.
* الدالة <code>[[Arduino/advanced io/pulsein|pulseIn()‎]]</code>: تحسب طول نبضةٍ (إمَّا <code>HIGH</code> أو <code>LOW</code>) على رجل محدَّدة.
* الدالة <code>[[Arduino/advanced io/pulseinlong|pulseInLong()‎]]</code> هي دالةٌ بديلةٌ محسَّنةٌ للدالة <code>[[Arduino/advanced io/pulsein|pulseIn()‎]]</code>، إذ يمكنها التعامل مع نبضات ومقاطعات طويلة متأثرة بحالات مختلفة.
* الدالة <code>[[Arduino/advanced io/shiftin|shiftIn()‎]]</code>: تزيح بايتًا من البيانات من رجل محدَّدة إلى متغيِّر مقدار بتٍّ واحدٍ في كل مرة تتغير فيها حالة النبضة على رجل أخرى إلى <code>HIGH</code>.
* الدالة <code>[[Arduino/advanced io/tone|tone()‎]]</code>: تولِّد موجةً مربَّعةً بتردد محدَّد (وبنسبة 50% لدورة العمل [duty cycle]) على رجل معيَّنة.

==مصادر==
* [https://www.arduino.cc/reference/en/language/functions/advanced-io/shiftout/ صفحة الدالة shiftOut()‎ في توثيق أردوينو الرسمي.]
[[تصنيف: Arduino]]
[[تصنيف: Arduino Function]]
[[تصنيف: Arduino I/O]]
[[تصنيف: Arduino Advanced I/O]]